***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*May 24, 2019                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt BAS316-AU 2 1 
.param
+vc0 = 6.145e-9		vc1 = 5.283e-11		vc2 = 5.052e-10		vc3 = 1.517e-2
+tc1 = 1.432e-1		tc2 = 4.119e-2		tc3 = 5.205e-2		tc4 = 1.000e-3	
d1 2 1 diode
;g1 1 2 value = {(vc0+vc1*v(1,2)+vc2*v(1,2)*v(1,2))*(1.0+tc3*(temp-25)*exp(tc4*(temp-25)))}
g1 1 2 value = {(vc0+vc1*v(1,2))*(1.0+tc1*(temp-25)*exp(tc2*(temp-25)))+vc2*exp(vc3*v(1,2))*(1.0+tc3*(temp-25)*exp(tc4*(temp-25)))}
.model diode d
***** flag parameter *****
+level = 1
***** dc model parameter *****
+ is = 2.665e-9		   n = 1.863		 rs = 1.250		ikf = 1.116
+ibv = 0.1e-3		 nbv = 1		 bv = 110
***** capacitance parameter *****
+cjo = 7.122e-13	   m = 0.036		 vj = 1.141e1
+ fc = 0.5
***** temperature coefficient *****
+tnom = 25		  eg = 1.161	 	xti = 3
+trs1 = 1.210e-3 	trs2 = 3.851e-6
+tikf = 9.511e-2
.ends BAS316-AU
*$
